116 lines
4.0 KiB
Tcl
116 lines
4.0 KiB
Tcl
# dialog.tcl --
|
|
#
|
|
# This file defines the procedure tk_dialog, which creates a dialog
|
|
# box containing a bitmap, a message, and one or more buttons.
|
|
#
|
|
# $Header: /user6/ouster/wish/library/RCS/dialog.tcl,v 1.4 93/08/16 16:59:52 ouster Exp $ SPRITE (Berkeley)
|
|
#
|
|
# Copyright (c) 1992-1993 The Regents of the University of California.
|
|
# All rights reserved.
|
|
#
|
|
# Permission is hereby granted, without written agreement and without
|
|
# license or royalty fees, to use, copy, modify, and distribute this
|
|
# software and its documentation for any purpose, provided that the
|
|
# above copyright notice and the following two paragraphs appear in
|
|
# all copies of this software.
|
|
#
|
|
# IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
|
|
# DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
|
|
# OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
|
|
# CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
#
|
|
# THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
|
|
# INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
|
|
# AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
|
|
# ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
|
|
# PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS.
|
|
#
|
|
|
|
#
|
|
# tk_dialog:
|
|
#
|
|
# This procedure displays a dialog box, waits for a button in the dialog
|
|
# to be invoked, then returns the index of the selected button.
|
|
#
|
|
# Arguments:
|
|
# w - Window to use for dialog top-level.
|
|
# title - Title to display in dialog's decorative frame.
|
|
# text - Message to display in dialog.
|
|
# bitmap - Bitmap to display in dialog (empty string means none).
|
|
# default - Index of button that is to display the default ring
|
|
# (-1 means none).
|
|
# args - One or more strings to display in buttons across the
|
|
# bottom of the dialog box.
|
|
|
|
proc tk_dialog {w title text bitmap default args} {
|
|
global tk_priv
|
|
|
|
# 1. Create the top-level window and divide it into top
|
|
# and bottom parts.
|
|
|
|
catch {destroy $w}
|
|
toplevel $w -class Dialog
|
|
wm title $w $title
|
|
wm iconname $w Dialog
|
|
frame $w.top -relief raised -bd 1
|
|
pack $w.top -side top -fill both
|
|
frame $w.bot -relief raised -bd 1
|
|
pack $w.bot -side bottom -fill both
|
|
|
|
# 2. Fill the top part with bitmap and message.
|
|
|
|
message $w.msg -width 3i -text $text \
|
|
-font -Adobe-Times-Medium-R-Normal-*-180-*
|
|
pack $w.msg -in $w.top -side right -expand 1 -fill both -padx 5m -pady 5m
|
|
if {$bitmap != ""} {
|
|
label $w.bitmap -bitmap $bitmap
|
|
pack $w.bitmap -in $w.top -side left -padx 5m -pady 5m
|
|
}
|
|
|
|
# 3. Create a row of buttons at the bottom of the dialog.
|
|
|
|
set i 0
|
|
foreach but $args {
|
|
button $w.button$i -text $but -command "set tk_priv(button) $i"
|
|
if {$i == $default} {
|
|
frame $w.default -relief sunken -bd 1
|
|
raise $w.button$i $w.default
|
|
pack $w.default -in $w.bot -side left -expand 1 -padx 3m -pady 2m
|
|
pack $w.button$i -in $w.default -padx 2m -pady 2m \
|
|
-ipadx 2m -ipady 1m
|
|
bind $w <Return> "$w.button$i flash; set tk_priv(button) $i"
|
|
} else {
|
|
pack $w.button$i -in $w.bot -side left -expand 1 \
|
|
-padx 3m -pady 3m -ipadx 2m -ipady 1m
|
|
}
|
|
incr i
|
|
}
|
|
|
|
# 4. Withdraw the window, then update all the geometry information
|
|
# so we know how big it wants to be, then center the window in the
|
|
# display and de-iconify it.
|
|
|
|
wm withdraw $w
|
|
update idletasks
|
|
set x [expr [winfo screenwidth $w]/2 - [winfo reqwidth $w]/2 \
|
|
- [winfo vrootx [winfo parent $w]]]
|
|
set y [expr [winfo screenheight $w]/2 - [winfo reqheight $w]/2 \
|
|
- [winfo vrooty [winfo parent $w]]]
|
|
wm geom $w +$x+$y
|
|
wm deiconify $w
|
|
|
|
# 5. Set a grab and claim the focus too.
|
|
|
|
set oldFocus [focus]
|
|
grab $w
|
|
focus $w
|
|
|
|
# 6. Wait for the user to respond, then restore the focus and
|
|
# return the index of the selected button.
|
|
|
|
tkwait variable tk_priv(button)
|
|
destroy $w
|
|
focus $oldFocus
|
|
return $tk_priv(button)
|
|
}
|