# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/oracle-jre-bin/oracle-jre-bin-1.7.0.45.ebuild,v 1.3 2013/10/19 19:50:38 ago Exp $

EAPI="5"

inherit java-vm-2 eutils prefix versionator

MY_PV="$(get_version_component_range 2)u$(get_version_component_range 4)"
S_PV="$(replace_version_separator 3 '_')"

BUILD="13"
BUILDDATE="18_dec_2014"
SUFFIX=".tar.gz"
ARMV5_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-sflt-headless-${BUILDDATE}${SUFFIX}"
ARMV6_SF_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-sflt-client_headless-${BUILDDATE}${SUFFIX}"
ARMV6_HF_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-hflt-client_headless-${BUILDDATE}${SUFFIX}"
ARMV7_SF_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-sflt-client_headful-${BUILDDATE}${SUFFIX}"
ARMV7_HF_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-hflt-client_headful-${BUILDDATE}${SUFFIX}"
X86_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-i586-headless-${BUILDDATE}${SUFFIX}"

# This URIs need updating when bumping!
JRE_URI="http://www.oracle.com/technetwork/java/embedded/downloads/javase/index.html"
JCE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jce-7-download-432124.html"

JCE_DIR="UnlimitedJCEPolicy"
JCE_FILE="${JCE_DIR}JDK7.zip"

DESCRIPTION="Oracle's Java SE Runtime Environment"
HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
SRC_URI="
	arm? ( ${ARMV5_AT} ${ARMV6_SF_AT} ${ARMV7_SF_AT} ${ARMV6_HF_AT} ${ARMV7_HF_AT} )
	x86? ( ${X86_AT} )
	jce? ( ${JCE_FILE} )"

LICENSE="Oracle-BCLA-JavaSE"
SLOT="1.7"
KEYWORDS="arm x86"
IUSE="X alsa fontconfig jce pax_kernel"

RESTRICT="fetch strip"
QA_PREBUILT="*"

RDEPEND="
	X? (
		x11-libs/libXext
		x11-libs/libXi
		x11-libs/libXrender
		x11-libs/libXtst
		x11-libs/libX11
	)
	alsa? ( media-libs/alsa-lib )
	fontconfig? ( media-libs/fontconfig )
	!prefix? ( sys-libs/glibc )"
# scanelf won't create a PaX header, so depend on paxctl to avoid fallback
# marking. #427642
DEPEND="
	jce? ( app-arch/unzip )
	pax_kernel? ( sys-apps/paxctl )"

S="${WORKDIR}/ejre${S_PV}"

pkg_nofetch() {
	if use x86; then
		AT=${X86_AT}
	elif use arm; then
		AT="${ARMV5_AT} ${ARMV6_SF_AT} ${ARMV6_HF_AT} ${ARMV7_SF_AT} ${ARMV7_HF_AT}"
	fi

	einfo "Please download '${AT}' from:"
	einfo "'${JRE_URI}'"
	einfo "and move it to '${DISTDIR}'"

	if use jce; then
		einfo "Also download '${JCE_FILE}' from:"
		einfo "'${JCE_URI}'"
		einfo "and move it to '${DISTDIR}'"
	fi
}

src_unpack() {
	einfo "Unpacking for arch ${CHOST/-*/}"

	if [[ ${CHOST} = armv5* ]]; then
		unpack ${ARMV5_AT}
	elif [[ ${CHOST} = armv6* ]]; then
		if [[ ${CHOST} = *hardfloat* ]]; then
			unpack ${ARMV6_HF_AT}
		else
			unpack ${ARMV6_SF_AT}
		fi
	elif [[ ${CHOST} = armv7* ]]; then
		if [[ ${CHOST} = *hardfloat* ]]; then
			unpack ${ARMV7_HF_AT}
		else
			unpack ${ARMV7_SF_AT}
		fi
	else
		unpack ${X86_AT}
	fi

	if use jce; then
		unpack ${JCE_FILE}
	fi
}

src_prepare() {
	if use jce; then
		mv "${WORKDIR}"/${JCE_DIR} lib/security/ || die
	fi
}

src_compile() {
	# This needs to be done before CDS - #215225
	java-vm_set-pax-markings "${S}"

	# see bug #207282
	einfo "Creating the Class Data Sharing archives"
	case ${ARCH} in
		arm)
			bin/java -client -Xshare:dump || die
			;;
		x86)
			bin/java -client -Xshare:dump || die
			;;
		*)
			bin/java -server -Xshare:dump || die
			;;
	esac

	# Create files used as storage for system preferences.
	mkdir .systemPrefs || die
	touch .systemPrefs/.system.lock || die
	touch .systemPrefs/.systemRootModFile || die
}

src_install() {
	local dest="/opt/${P}"
	local ddest="${ED}${dest}"

	dodir "${dest}"
	cp -pPR bin lib "${ddest}" || die

	# Remove empty dirs we might have copied
	find "${D}" -type d -empty -exec rmdir -v {} + || die

	dodoc COPYRIGHT README THIRDPARTYLICENSEREADME.txt

	if use jce; then
		dodir ${dest}/lib/security/strong-jce
		mv "${ddest}"/lib/security/US_export_policy.jar \
			"${ddest}"/lib/security/strong-jce || die
		mv "${ddest}"/lib/security/local_policy.jar \
			"${ddest}"/lib/security/strong-jce || die
		dosym "${dest}"/lib/security/${JCE_DIR}/US_export_policy.jar \
			"${dest}"/lib/security/US_export_policy.jar
		dosym "${dest}"/lib/security/${JCE_DIR}/local_policy.jar \
			"${dest}"/lib/security/local_policy.jar
	fi

	# Prune all fontconfig files so libfontconfig will be used and only install
	# a Gentoo specific one if fontconfig is disabled.
	# http://docs.oracle.com/javase/7/docs/technotes/guides/intl/fontconfig.html
	rm "${ddest}"/lib/fontconfig.* || die
	if ! use fontconfig; then
		cp "${FILESDIR}"/fontconfig.Gentoo.properties "${T}"/fontconfig.properties || die
		eprefixify "${T}"/fontconfig.properties
		insinto "${dest}"/lib/
		doins "${T}"/fontconfig.properties
	fi

	set_java_env
	java-vm_revdep-mask
	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
}