@Echo off
if exist "%PROGRAMFILES(X86)%" (set arch=x64) ELSE (set arch=x86)

"%windir%\system32\reg.exe" query "HKU\S-1-5-19" >nul 2>&1 && (
goto :checkok
) || (
echo      -------
echo  *** WARNING ***
echo      -------
echo.
echo.
echo ADMINISTRATOR PRIVILEGES NOT DETECTED!
echo ______________________________________
echo.
echo This script must be able to run with administrator
echo privileges.
echo.
echo To do so, right click on this script and select 'Run As Administrator'
echo.
echo.
echo Press any key to exit...
pause >nul
goto :eof
)

:checkok

if exist "%temp%\list.txt" (del "%temp%\list.txt")

if %arch% neq x64 goto :x64skip
echo Uninstalling existing Visual C++ x86 Runtime Redistributables
echo (please wait as this process may take a few moments)

reg query hklm\Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall /f "Microsoft Visual C++ 2005 Redistributable" /s >>"%temp%\list.txt"

for /f "delims=\ tokens=8" %%a in ('type "%temp%\list.txt"') do ("%windir%\system32\msiexec.exe" /X%%a /q)

del "%temp%\list.txt"

goto :install

:x64skip
echo Uninstalling existing Visual C++ %arch% Runtime Redistributables
echo (please wait as this process may take a few moments)

reg query hklm\software\microsoft\windows\currentversion\uninstall /f "Microsoft Visual C++ 2005 Redistributable" /s >>"%temp%\list.txt"

for /f "delims=\ tokens=7" %%a in ('type "%temp%\list.txt"') do ("%windir%\system32\msiexec.exe" /X%%a /q)

del "%temp%\list.txt"

:install

"%windir%\system32\msiexec.exe" /i vcredist.msi /q transforms=2k5-x86.mst

:eof