sereby.aio/CLIENT_DATA/MSVC08_x86_Install.cmd

@Echo off
SET VCDIR=%~dp0
cd %VCDIR%\..\..\..
SET GNUPARENTDIR=%cd%

"%windir%\system32\reg.exe" query "HKU\S-1-5-19" >nul 2>&1 && (
goto :checkok
) || (
echo      -------
echo  *** WARNING ***
echo      -------
echo.
echo.
echo ADMINISTRATOR PRIVILEGES NOT DETECTED!
echo ______________________________________
echo.
echo This script must be able to run with administrator
echo privileges.
echo.
echo To do so, right click on this script and select 'Run As Administrator'
echo.
echo.
echo Press any key to exit...
pause >nul
goto :eof
)

:checkok

if exist "%temp%\list.txt" (del "%temp%\list.txt")
if exist "%temp%\list1.txt" (del "%temp%\list1.txt")

echo Uninstalling existing Visual C++ 2008 x86 Runtime Redistributables
echo (please wait as this process may take a few moments)
wmic product where "name like 'Microsoft Visual C++ 2008 Redistributable - x86%%'" get name >>"%temp%\list.txt"
for /f "skip=1 delims=" %%a in ('type "%temp%\list.txt"') do (echo "%%a")

echo Converting ucs-2 encoded list of installed products to utf-8
%GNUPARENTDIR%\GNU\iconv.exe -f UCS-2 -t UTF-8 %temp%\list.txt > %temp%\list1.txt
echo CleanUp some errors in the list file
%GNUPARENTDIR%\GNU\sed.exe -e "s/\s*$//g" -i %temp%\list1.txt
echo Converting back utf-8 encoded list of installed products to ucs-2
%GNUPARENTDIR%\GNU\iconv.exe -f UTF-8 -t UCS-2 %temp%\list1.txt > %temp%\list.txt

echo start uninstalling old versions of product
for /f "skip=1 delims=" %%a in ('type "%temp%\list1.txt"') do (echo "%%a")
for /f "skip=1 delims=" %%a in ('type "%temp%\list1.txt"') do (wmic product where "name like '%%a%'" call uninstall /nointeractive)

echo CleanUp Tempory files
del "%temp%\list.txt"
del "%temp%\list1.txt"

echo Install latest version of Visual C++ 2008 x86 Runtime Redistributables
echo (please wait as this process may take a few moments)
"%windir%\system32\msiexec.exe" /i "%VCDIR%\vc_red.msi" /q transforms="%VCDIR%\2k8-x86.mst"

:eof