; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.
; credits: http://www.opsi.org/en/credits/

[Actions]
requiredWinstVersion >= "4.11.2.6"

DefVar $UninstallProgram32$
DefVar $UninstallProgramOld32$
DefVar $IniFile32$
DefVar $UninstallProgram64$
DefVar $UninstallProgramOld64$
DefVar $IniFile64$
DefVar $IniCfgFile$
DefVar $LogDir$
DefVar $ProductId$  
DefVar $MinimumSpace$
DefVar $InstallDir32$
DefVar $InstallDir64$
DefVar $ExitCode$
DefVar $INST_SystemType$
DefVar $INST_architecture$
DefVar $OLD_VERSION$
DefVar $OLD_CREATOR_TAG$
DefVar $OLD_RELEASE$

DefVar $openvpn_userpasswd$
DefVar $UserExists$

DefStringlist $ResultList$
DefStringlist $ResultList2$

Set $INST_SystemType$ = GetSystemType
set $INST_architecture$ = GetProductProperty("install_architecture","system specific")
Set $openvpn_userpasswd$ = RandomStr


Set $LogDir$ = "%SystemDrive%\tmp"

; The token BUILDER_VARIABLES will be replaced by opsi-builder.sh
; and adds the following variables:
;   from builder-product.cfg :  all variables definded by attribute WINST[index]
;   from builder-product.cfg :  VENDOR PN VERSION RELEASE PRIORITY ADVICE TYPE   
;   from opsi-builder.cfg    :  CREATOR_TAG CREATOR_NAME CREATOR_EMAIL           
;   auto generated winst-variables
;         $IconFile$: path to product picture
;
@@BUILDER_VARIABLES@@

; ----------------------------------------------------------------
; - Please edit the following values                             -
; ----------------------------------------------------------------
;$ProductId$ should be the name of the product in opsi
; therefore please: only lower letters, no umlauts, 
; no white space use '-' as a seperator
Set $MinimumSpace$    = "30 MB"
; the path were we find the product after the installation
Set $InstallDir32$      = "%ProgramFiles32Dir%\OpenVPN"
Set $InstallDir64$      = "%ProgramFiles64Dir%\OpenVPN"
; ----------------------------------------------------------------

Set $IniCfgFile$ = "%ScriptPath%\opsi-" + $ProductId$ + ".ini"

if not(HasMinimumSpace ("%SystemDrive%", $MinimumSpace$))
	LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for " + $ProductId$
	isFatalError
	; Stop process and set installation status to failed
else
	comment "Show product picture"
	ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $NAME$
	
	if FileExists("%ScriptPath%\delsub3264.ins")
		comment "Start uninstall sub section"
		Sub "%ScriptPath%\delsub3264.ins"
	endif
	
	comment "installing OpenVPN Cert"
	Winbatch_install_cert
	Sub_check_exitcode

	comment "get the name of the admin group"
	comment "using psgetsid from sysinernals pstools"
	set $ResultList$ = getOutStreamFromSection("DosInAnIcon_get_admin_group")

	set $Group$ = takeString(6,$ResultList$)
	set $Group$ = takeString(1,splitstring($Group$,"\"))

	comment "Check if user exists."
	comment "If user exists, the password will be altered. Otherwise, the user will be created."
	set $ResultList2$ = getOutStreamFromSection("DosInAnIcon_checkuser")
	set $UserExists$ = takeString(0,$ResultList2$)

	setLogLevel=0
 
	comment "create our local user"
	if $UserExists$ = "no"
		DosInAnIcon_makeadmin
	else
		DosInAnIcon_alter_pw
	endif

	setLogLevel=3

	comment "installing"

	if (($INST_SystemType$ = "x86 System") and ($INST_architecture$ = "system specific")) or ($INST_architecture$ = "both") or ($INST_architecture$ = "32 only")
		Message "Installing " + $ProductId$ + " "+ $VERSION$ + "-" + $CREATOR_TAG$ + $RELEASE$ + " 32 Bit..."
		comment "Start setup program"
		ChangeDirectory "%SCRIPTPATH%"
		Winbatch_install_32
		Sub_check_exitcode
		comment "Copy files"
		Files_install_32 /32Bit
		comment "Patch Registry"
		Registry_install /32Bit
		comment "Create shortcuts"
		LinkFolder_install_32
	endif

	if ($INST_SystemType$ = "64 Bit System") and (($INST_architecture$ = "system specific") or ($INST_architecture$ = "both") or ($INST_architecture$ = "64 only"))
		Message "Installing " + $ProductId$ + " "+ $VERSION$ + "-" + $CREATOR_TAG$ + $RELEASE$ + " 64 Bit..."
		comment "Start setup program"
		ChangeDirectory "%SCRIPTPATH%"
		Winbatch_install_64
		Sub_check_exitcode
		comment "Copy files"
		Files_install_64 /64Bit
		comment "Patch Registry"
		Registry_install /64Bit
		comment "Create shortcuts"
		LinkFolder_install_64
	endif
	
endif

[DosInAnIcon_get_admin_group]
@echo off
"%ScriptPath%\ALL\PsGetsid.exe" /accepteula S-1-5-32-544

[DosInAnIcon_checkuser]
@echo off
net user openvpn >nul 2>&1 && echo yes || echo no

[DosInAnIcon_makeadmin]
NET USER openvpn $openvpn_userpasswd$ /ADD /comment:"Local User created by OpenVPN opsi-package" /fullname:"Local User by Opsi OpenVPN" /passwordchg:no /passwordreq:yes /expires:never /active:yes
NET LOCALGROUP $Group$ /ADD openvpn

[DosInAnIcon_alter_pw]
NET USER openvpn $openvpn_userpasswd$

[Winbatch_install_cert]
certutil -addstore "TrustedPublisher" "%ScriptPath%\OpenVPN-Certificate.cer"

[Winbatch_install_32]
"$Install32Exe$" /S
"%ScriptPath%\ALL\CPAU.exe" -u openvpn -p $openvpn_userpasswd$ -ex "$InstallDir32$\bin\openvpn-gui.exe" -enc -file "$InstallDir32$\openvpn.job" -crc "$InstallDir32$\bin\openvpn-gui.exe"

[Files_install_32]
; copy the ini file to the InstallDir
copy "$IniCfgFile$" "$InstallDir32$"

; Example of recursively copying some files into the installation directory:
;
copy -s "%ScriptPath%\ALL\CPAU.exe" "$InstallDir32$"

[Winbatch_install_64]
"$Install64Exe$" /S
"%ScriptPath%\ALL\CPAU.exe" -u openvpn -p $openvpn_userpasswd$ -ex "$InstallDir64$\bin\openvpn-gui.exe" -enc -file "$InstallDir64$\openvpn.job" -crc "$InstallDir64$\bin\openvpn-gui.exe"

[Files_install_64]
; copy the ini file to the InstallDir
copy "$IniCfgFile$" "$InstallDir64$"

; Example of recursively copying some files into the installation directory:
;
copy -s "%ScriptPath%\ALL\CPAU.exe" "$InstallDir64$"

[Registry_install]
; Example of setting some values of an registry key:
;
; openkey [HKEY_LOCAL_MACHINE\Software\$ProductId$]
; set "name1" = "some string value"
; set "name2" = REG_DWORD:0001
; set "name3" = REG_BINARY:00 af 99 cd

[LinkFolder_install_32]
set_basefolder common_programs
set_subfolder OpenVPN

set_link
	name: OpenVPN GUI
	target: $InstallDir32$/CPAU.exe
	parameters: -dec -file $InstallDir32$\openvpn.job
	working_dir: $InstallDir32$
	icon_file: $InstallDir32$\icon.ico
	icon_index:
end_link

set_basefolder common_desktopdirectory
set_subfolder ""

set_link
	name: OpenVPN GUI
	target: $InstallDir32$/CPAU.exe
	parameters: -dec -file $InstallDir32$\openvpn.job
	working_dir: $InstallDir32$
	icon_file: $InstallDir32$\icon.ico
	icon_index:
end_link

[LinkFolder_install_64]
set_basefolder common_programs
set_subfolder OpenVPN

set_link
	name: OpenVPN GUI
	target: $InstallDir64$/CPAU.exe
	parameters: -dec -file $InstallDir64$\openvpn.job
	working_dir: $InstallDir64$
	icon_file: $InstallDir64$\icon.ico
	icon_index:
end_link

set_basefolder common_desktopdirectory
set_subfolder ""

set_link
	name: OpenVPN GUI
	target: $InstallDir64$/CPAU.exe
	parameters: -dec -file $InstallDir64$\openvpn.job
	working_dir: $InstallDir64$
	icon_file: $InstallDir64$\icon.ico
	icon_index:
end_link

[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif