; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.
; credits: http://www.opsi.org/credits/

[Actions]
; at least 4.11.2, tested with 4.11.3.3
requiredWinstVersion >= "4.11.3.3"

DefVar $LogDir$
DefVar $ProductId$  
DefVar $MinimumSpace$
DefVar $ExitCode$
DefVar $INST_SystemType$
DefVar $INST_architecture$

Set $INST_SystemType$ = GetSystemType

;
; get product properties for options
;
; multi-value values are return as string, seperated by ",", eg. "value1,value2,value3",
; therefore we replace "," by " " (split, compose)
;
DefVar $Options$
Set $Options$ = composeString( splitString ( GetProductProperty("options",""), "," ), " " )

comment "options: " + $Options$

Set $LogDir$ = "%SystemDrive%\tmp"

; The token BUILDER_VARIABLES will be replaced by opsi-builder.sh
; and adds the following variables:
;   from builder-product.cfg :  all variables definded by attribute WINST[index]
;   from builder-product.cfg :  VENDOR PN VERSION RELEASE PRIORITY ADVICE TYPE   
;   from opsi-builder.cfg    :  CREATOR_TAG CREATOR_NAME CREATOR_EMAIL           
;   auto generated winst-variables
;         $IconFile$: path to product picture
;
@@BUILDER_VARIABLES@@

; ----------------------------------------------------------------
; - Please edit the following values                             -
; ----------------------------------------------------------------
;$ProductId$ should be the name of the product in opsi
; therefore please: only lower letters, no umlauts, 
; no white space use '-' as a seperator
Set $MinimumSpace$    = "1000 MB"
; ----------------------------------------------------------------

if not(HasMinimumSpace ("%SystemDrive%", $MinimumSpace$))
	LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for " + $ProductId$
	isFatalError
	; Stop process and set installation status to failed
endif

comment "Show product picture"
ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductId$
	
comment "installing"
Message "Installing " + $ProductId$ + " ..."

comment "Start setup program"
;Winbatch_install
Shellbatch_install /winst /sysnative

; include wsusoffline logfile (last 1000 lines)
includelog "%Systemroot%\wsusofflineupdate.log" "1000"

; check exit code, reboot is required
Sub_check_exitcode

[ShellBatch_install]
@rem remove old wsusoffline logfile
del /q "%Systemroot%\wsusofflineupdate.log"
call "%ScriptPath%\client\cmd\DoUpdate.cmd" $Options$
exit %ERRORLEVEL%

[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
        comment "Looks good: setup program gives exitcode zero"
else
        comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
        if ($ExitCode$ = "1605")
                comment "ERROR_UNKNOWN_PRODUCT  1605    This action is only valid for products that are currently installed."
                comment "Uninstall of a not installed product failed - no problem"
        else
                if ($ExitCode$ = "1641")
                        comment "looks good: setup program gives exitcode 1641"
                        comment "ERROR_SUCCESS_REBOOT_INITIATED 1641    The installer has initiated a restart. This message is indicative of a success."
                        ExitWindows /Reboot
                else
                        if ($ExitCode$ = "3010")
                                comment "looks good: setup program gives exitcode 3010"
                                comment "ERROR_SUCCESS_REBOOT_REQUIRED  3010    A restart is required to complete the install. This message is indicative of a success."
                                ExitWindows /Reboot
                        else
                            if ($ExitCode$ = "3011")
                                comment "looks good: setup program gives exitcode 3011"
                                comment "ERROR_SUCCESS: wsusoffline requires reboot and rerun."
                                ExitWindows /ImmediateReboot
                            else
                                logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
                                isFatalError
                            endif
                        endif
                endif
        endif
endif