; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib gmbh
; and published under the Terms of the General Public License.
; credits: http://www.opsi.org/en/credits/


Set $UninstallProgramOld$ = $InstallDir$ + "\" + $UninstallProg$
Set $UninstallProgram$ = $InstallDir$ + "\unins000.exe"
Set $IniFile$ = $InstallDir$ + "\opsi-" + $ProductId$ + ".ini"

if FileExists($IniFile$)
	Set $OLD_VERSION$ = GetValueFromInifile($IniFile$,"COMMON","VERSION","")
	Set $OLD_CREATOR_TAG$ = GetValueFromInifile($IniFile$,"COMMON","CREATOR_TAG","")
	Set $OLD_RELEASE$ = GetValueFromInifile($IniFile$,"COMMON","RELEASE","")
endif
Message "Uninstalling " + $ProductId$ + " " + $OLD_VERSION$ + "-" + $OLD_CREATOR_TAG$ + $OLD_RELEASE$ + " ..."


if FileExists($IniFile$)
        Set $UninstallProgramOld$ = GetValueFromInifile($IniFile$,"X86","UninstallProg","XXXXXXXX.exe")
	if FileExists($UninstallProgramOld$)
		comment "Uninstall program found, starting uninstall"
		Dosbatch_uninstall
		sub_check_exitcode
		Winbatch_uninstall_old
		sub_check_exitcode
	endif
endif
if FileExists($UninstallProgram$)
	comment "Uninstall program found, starting uninstall"
	Dosbatch_uninstall
	sub_check_exitcode
	Winbatch_uninstall
	sub_check_exitcode
endif

comment "Delete files"
Files_uninstall /32Bit

comment "Cleanup registry"
Registry_uninstall /32Bit

comment "Delete program shortcuts"
LinkFolder_uninstall

[Dosbatch_uninstall]
; PuTTY 0.58+ uninstallers call 'putty -cleanup-during-uninstall' during uninstall. This causes a pop-up to appear which breaks the silent uninstall.
copy /Y "%System%\print.exe" "$InstallDir$\putty.exe"

[Winbatch_uninstall_old]
"$UninstallProgramOld$" /sp- /verysilent /norestart


[Winbatch_uninstall]
"$UninstallProgram$" /sp- /verysilent /norestart

[Files_uninstall]
; Example for recursively deleting the installation directory:
;
del -sf "$InstallDir$\"

[Registry_uninstall]
; Example of deleting a registry key:
;
; deletekey [HKEY_LOCAL_MACHINE\Software\$ProductId$]

[LinkFolder_uninstall]
; Example of deleting a folder from AllUsers startmenu:
;
; set_basefolder common_programs
; delete_subfolder $ProductId$
;
; Example of deleting a shortcut from AllUsers desktop:
;
; set_basefolder common_desktopdirectory
; set_subfolder ""
; delete_element $ProductId$

[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif