adobe.photoshopcs2/CLIENT_DATA/setup32.ins

; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.
; credits: http://www.opsi.org/en/credits/

[Actions]
requiredWinstVersion >= "4.11.2.6"

DefVar $MsiIdOld$
DefVar $IniFile$
DefVar $IniCfgFile$
DefVar $LogDir$
DefVar $ProductId$  
DefVar $MinimumSpace$
DefVar $InstallDir$
DefVar $ExitCode$
DefVar $LicenseRequired$
DefVar $LicenseKey$
DefVar $LicensePool$
DefVar $OLD_VERSION$
DefVar $OLD_CREATOR_TAG$
DefVar $OLD_RELEASE$

DefStringList $languageInfo$
set  $languageInfo$ = getLocaleInfoMap
DefVar $LanguageId$
set $LanguageId$ = getValue("default_language_id_decimal", $languageInfo$)

DefStringList $ShortProgramFiles32List$
set $ShortProgramFiles32List$ = getOutStreamFromSection ('DosInAnIcon_path')
DefVar $ShortProgramFiles32Dir$
set $ShortProgramFiles32Dir$ = takeString (-1, $ShortProgramFiles32List$)

Set $LogDir$ = "%SystemDrive%\tmp"

; The token BUILDER_VARIABLES will be replaced by opsi-builder.sh
; and adds the following variables:
;   from builder-product.cfg :  all variables definded by attribute WINST[index]
;   from builder-product.cfg :  VENDOR PN VERSION RELEASE PRIORITY ADVICE TYPE   
;   from opsi-builder.cfg    :  CREATOR_TAG CREATOR_NAME CREATOR_EMAIL           
;   auto generated winst-variables
;         $IconFile$: path to product picture
;
@@BUILDER_VARIABLES@@

; ----------------------------------------------------------------
; - Please edit the following values                             -
; ----------------------------------------------------------------
;$ProductId$ should be the name of the product in opsi
; therefore please: only lower letters, no umlauts, 
; no white space use '-' as a seperator
Set $MinimumSpace$    = "600 MB"
; the path were we find the product after the installation
Set $InstallDir$      = $ShortProgramFiles32Dir$ + "\Adobe\Adobe Photoshop CS2"
Set $LicenseRequired$ = "true"
Set $LicensePool$     = "p_" + $ProductId$
; ----------------------------------------------------------------

Set $IniCfgFile$ = "%ScriptPath%\opsi-" + $ProductId$ + ".ini"

if not(HasMinimumSpace ("%SystemDrive%", $MinimumSpace$))
	LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for " + $ProductId$
	isFatalError "No Space"
	; Stop process and set installation status to failed
else
	comment "Show product picture"
	ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $NAME$
	
	if FileExists("%ScriptPath%\delsub32.ins")
		comment "Start uninstall sub section"
		Sub "%ScriptPath%\delsub32.ins"
	endif
	
	Message "Installing " + $ProductId$ + " "+ $VERSION$ + "-" + $CREATOR_TAG$ + $RELEASE$ + " ..."
	
	if $LicenseRequired$ = "true"
		comment "Licensing required, reserve license and get license key"
		Sub_get_licensekey
	endif
	
	comment "Start setup program"
	ChangeDirectory "%SCRIPTPATH%"
	Files_delete

	Winbatch_prepare
	Sub_check_exitcode

	Files_copy
	Sub_check_exitcode

	DosInAnIcon_license
	Sub_check_exitcode

	Winbatch_install
	Sub_check_exitcode

	Winbatch_update_bridge
	Sub_check_exitcode

	Files_delete

	comment "Copy files"
	Files_install /32Bit
	
	comment "Patch Registry"
	Registry_install /32Bit
	
	comment "Create shortcuts"
	LinkFolder_install
	
endif

[DosInAnIcon_path]
%ScriptPath%\short.bat "%ProgramFiles32Dir%"

[DosInAnIcon_license]
inifile $LogDir$\$ProductId$\Abcpy.ini [OEM Install] SERIALNUMBER=$Licensekey$
inifile $LogDir$\$ProductId$\Abcpy.ini [OEM Install] USERNAME=%PCName%
inifile $LogDir$\$ProductId$\Abcpy.ini [OEM Install] COMPANYNAME=%IPName%
inifile $LogDir$\$ProductId$\Abcpy.ini [OEM Install] INSTALLDIR=$InstallDir$

[Winbatch_install]
msiexec /i "$LogDir$\$ProductId$\commonfilesinstaller\Adobe Common File Installer.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! ALLUSERS=1 REBOOT=ReallySuppress
msiexec /i "$LogDir$\$ProductId$\help center\Adobe Help Center 1.0.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! ALLUSERS=1 REBOOT=ReallySuppress
msiexec /i "$LogDir$\$ProductId$\Adobe Photoshop CS2.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! ALLUSERS=1 REBOOT=ReallySuppress TRANSFORM="$LogDir$\$ProductId$\Adobe Photoshop CS2 902.mst"
msiexec /i "$LogDir$\$ProductId$\bridge\Adobe Bridge 1.0.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! ALLUSERS=1 REBOOT=ReallySuppress
; "$LogDir$\$ProductId$\setup.exe" /s /v /qn

[Winbatch_prepare]
msiexec /a "%ScriptPath%\X86\Core\Adobe Photoshop CS2.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! TARGETDIR="$LogDir$\$ProductId$\"
vcopy "%ScriptPath%\X86\Updater\Core\AdobeXMP.dll" "$LogDir$\$ProductId$\program files\Adobe\Adobe Photoshop CS2\AdobeXMP.dll"
vcopy "%ScriptPath%\X86\Updater\Core\HDRMergeAuto.8li" "$LogDir$\$ProductId$\program files\Adobe\Adobe Photoshop CS2\Zusatzmodule\Adobe Photoshop Only\Automatisieren\HDR-Mehrfachbelichtung-Aut.8li"
vcopy "%ScriptPath%\X86\Updater\Core\MMXCore.8BX"  "$LogDir$\$ProductId$\program files\Adobe\Adobe Photoshop CS2\Zusatzmodule\Erweiterungen\MMXCore.8BX"
vcopy "%ScriptPath%\X86\Updater\Core\MultiProcessor Support.8BX"  "$LogDir$\$ProductId$\program files\Adobe\Adobe Photoshop CS2\Zusatzmodule\Erweiterungen\Mehrprozessorunterst<73>tzung.8BX"
vcopy "%ScriptPath%\X86\Updater\Core\Photoshop.exe" "$LogDir$\$ProductId$\program files\Adobe\Adobe Photoshop CS2\Photoshop.exe"
msiexec /a "%ScriptPath%\X86\Core\commonfilesinstaller\Adobe Common File Installer.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! TARGETDIR="$LogDir$\$ProductId$\commonfilesinstaller"
msiexec /a "%ScriptPath%\X86\Core\help center\Adobe Help Center 1.0.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! TARGETDIR="$LogDir$\$ProductId$\help center"
msiexec /a "%ScriptPath%\X86\Core\bridge\Adobe Bridge 1.0.msi" /l* "$LogDir$\$ProductId$.install_log.txt" /qb! TARGETDIR="$LogDir$\$ProductId$\bridge"


[Winbatch_update_bridge]
"$UpdateBridge104Exe$"

[Files_delete]
del -sf "$LogDir$\$ProductId$\"

[Files_copy]
copy "%ScriptPath%\X86\Core\*.ini" "$LogDir$\$ProductId$\"
copy "%ScriptPath%\X86\Core\*.mst" "$LogDir$\$ProductId$\"

[Files_install]
; copy the ini file to the InstallDir
copy "$IniCfgFile$" "$InstallDir$"

; Example of recursively copying some files into the installation directory:
;
; copy -s "%ScriptPath%\files\*.*" "$InstallDir$\"

[Registry_install]
; Disable Registry window
openkey [HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Uninstall\Adobe Photoshop CS2 - $MsiId$]
set "EPIC_REGS_TYPE" = REG_DWORD:00000004
set "EPIC_REGS_STATE" = REG_DWORD:00000002
set "EPIC_REGS_LANG" = REG_DWORD:00000000
set "EPIC_REGS_COUNT" = REG_DWORD:00000000

openkey [HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Uninstall\$MsiId$]
set "EPIC_REGS_TYPE" = REG_DWORD:00000004
set "EPIC_REGS_STATE" = REG_DWORD:00000002
set "EPIC_REGS_LANG" = REG_DWORD:00000000
set "EPIC_REGS_COUNT" = REG_DWORD:00000000


[LinkFolder_install]
; Example of deleting a folder from AllUsers startmenu:
;
; set_basefolder common_programs
; delete_subfolder $ProductId$
;
; Example of creating an shortcut to the installed exe in AllUsers startmenu:
;
; set_basefolder common_programs
; set_subfolder $ProductId$
;
; set_link
; 	name: $ProductId$
; 	target: <path to the program>
; 	parameters:
; 	working_dir: $InstallDir$
; 	icon_file:
; 	icon_index:
; end_link
;
; Example of creating an shortcut to the installed exe on AllUsers desktop:
;
; set_basefolder common_desktopdirectory
; set_subfolder ""
;
; set_link
; 	name: $ProductId$
; 	target: <path to the program>
; 	parameters: <some_param>
; 	working_dir: $InstallDir$
; 	icon_file: <path to icon file>
; 	icon_index: 2
; end_link

[Sub_get_licensekey]
if opsiLicenseManagementEnabled
	comment "License management is enabled and will be used"

	comment "Trying to get a license key"
	Set $LicenseKey$ = demandLicenseKey ($LicensePool$)
	; If there is an assignment of exactly one licensepool to the product the following call is possible:
	; Set $LicenseKey$ = demandLicenseKey ("", $ProductId$)
	;
	; If there is an assignment of a license pool to a windows software id, it is possible to use:
	; DefVar $WindowsSoftwareId$
	; $WindowsSoftwareId$ = "..."
	; Set $LicenseKey$ = demandLicenseKey ("", "", $WindowsSoftwareId$)
	
	DefVar $ServiceErrorClass$
	set $ServiceErrorClass$ = getLastServiceErrorClass
	comment "Error class: " + $ServiceErrorClass$
	
	if $ServiceErrorClass$ = "None"
		comment "Everything fine, we got the license key '" + $LicenseKey$ + "'"
	else
		if $ServiceErrorClass$ = "LicenseConfigurationError"
			LogError "Fatal: license configuration must be corrected"
			LogError getLastServiceErrorMessage
			isFatalError
		else 
			if $ServiceErrorClass$ = "LicenseMissingError"
				LogError "Fatal: required license is not supplied"
				isFatalError
			endif
		endif
	endif
else
	LogError "Fatal: license required, but license management not enabled"
	isFatalError
endif


[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif