alexhudson
ba63bbc4ee
* make it work with automake 1.8 * simpler system for expanding path variables * make it work with older gm4 Thanks to Albert Lee <trisk@acm.jhu.edu> for these!
261 lines
8.1 KiB
Plaintext
261 lines
8.1 KiB
Plaintext
dnl as-ac-expand.m4 0.1.0
|
|
dnl autostars m4 macro for expanding directories using configure's prefix
|
|
dnl thomas@apestaart.org
|
|
|
|
dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
|
|
dnl
|
|
dnl example
|
|
dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
|
|
dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
|
|
|
|
AC_DEFUN([AS_AC_EXPAND],
|
|
[
|
|
EXP_VAR=[$1]
|
|
FROM_VAR=[$2]
|
|
|
|
dnl first expand prefix and exec_prefix if necessary
|
|
prefix_save=$prefix
|
|
exec_prefix_save=$exec_prefix
|
|
|
|
dnl if no prefix given, then use /usr/local, the default prefix
|
|
if test "x$prefix" = "xNONE"; then
|
|
prefix=$ac_default_prefix
|
|
fi
|
|
dnl if no exec_prefix given, then use prefix
|
|
if test "x$exec_prefix" = "xNONE"; then
|
|
exec_prefix=$prefix
|
|
fi
|
|
|
|
full_var="$FROM_VAR"
|
|
dnl loop until it doesn't change anymore
|
|
while true; do
|
|
new_full_var="`eval echo $full_var`"
|
|
if test "x$new_full_var"="x$full_var"; then break; fi
|
|
full_var=$new_full_var
|
|
done
|
|
|
|
dnl clean up
|
|
full_var=$new_full_var
|
|
AC_SUBST([$1], "$full_var")
|
|
|
|
dnl restore prefix and exec_prefix
|
|
prefix=$prefix_save
|
|
exec_prefix=$exec_prefix_save
|
|
])
|
|
|
|
dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
|
|
dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
|
|
dnl also defines GSTUFF_PKG_ERRORS on error
|
|
AC_DEFUN([PKG_CHECK_MODULES], [
|
|
succeeded=no
|
|
|
|
if test -z "$PKG_CONFIG"; then
|
|
AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
|
|
fi
|
|
|
|
if test "$PKG_CONFIG" = "no" ; then
|
|
echo "*** The pkg-config script could not be found. Make sure it is"
|
|
echo "*** in your path, or set the PKG_CONFIG environment variable"
|
|
echo "*** to the full path to pkg-config."
|
|
echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
|
|
else
|
|
PKG_CONFIG_MIN_VERSION=0.9.0
|
|
if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
|
|
AC_MSG_CHECKING(for $2)
|
|
|
|
if $PKG_CONFIG --exists "$2" ; then
|
|
AC_MSG_RESULT(yes)
|
|
succeeded=yes
|
|
|
|
AC_MSG_CHECKING($1_CFLAGS)
|
|
$1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
|
|
AC_MSG_RESULT($$1_CFLAGS)
|
|
|
|
AC_MSG_CHECKING($1_LIBS)
|
|
$1_LIBS=`$PKG_CONFIG --libs "$2"`
|
|
AC_MSG_RESULT($$1_LIBS)
|
|
else
|
|
$1_CFLAGS=""
|
|
$1_LIBS=""
|
|
## If we have a custom action on failure, don't print errors, but
|
|
## do set a variable so people can do so.
|
|
$1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
|
|
ifelse([$4], ,echo $$1_PKG_ERRORS,)
|
|
fi
|
|
|
|
AC_SUBST($1_CFLAGS)
|
|
AC_SUBST($1_LIBS)
|
|
else
|
|
echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
|
|
echo "*** See http://www.freedesktop.org/software/pkgconfig"
|
|
fi
|
|
fi
|
|
|
|
if test $succeeded = yes; then
|
|
ifelse([$3], , :, [$3])
|
|
else
|
|
ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
|
|
fi
|
|
])
|
|
|
|
|
|
|
|
dnl a macro to check for ability to create python extensions
|
|
dnl AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
|
|
dnl function also defines PYTHON_INCLUDES
|
|
AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
|
|
[AC_REQUIRE([AM_PATH_PYTHON])
|
|
AC_MSG_CHECKING(for headers required to compile python extensions)
|
|
dnl deduce PYTHON_INCLUDES
|
|
py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
|
|
py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
|
|
PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
|
|
if test "$py_prefix" != "$py_exec_prefix"; then
|
|
PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
|
|
fi
|
|
AC_SUBST(PYTHON_INCLUDES)
|
|
dnl check if the headers exist:
|
|
save_CPPFLAGS="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
|
|
AC_TRY_CPP([#include <Python.h>],dnl
|
|
[AC_MSG_RESULT(found)
|
|
$1],dnl
|
|
[AC_MSG_RESULT(not found)
|
|
$2])
|
|
CPPFLAGS="$save_CPPFLAGS"
|
|
])
|
|
|
|
dnl AM_PATH_CHECK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
|
dnl Test for check, and define CHECK_CFLAGS and CHECK_LIBS
|
|
dnl
|
|
|
|
AC_DEFUN([AM_PATH_CHECK],
|
|
[
|
|
AC_ARG_WITH([check],
|
|
[ --with-check=PATH prefix where check is installed [default=auto]])
|
|
|
|
min_check_version=ifelse([$1], ,0.8.2,$1)
|
|
|
|
AC_MSG_CHECKING(for check - version >= $min_check_version)
|
|
|
|
if test x$with_check = xno; then
|
|
AC_MSG_RESULT(disabled)
|
|
ifelse([$3], , AC_MSG_ERROR([disabling check is not supported]), [$3])
|
|
else
|
|
if test "x$with_check" != x; then
|
|
CHECK_CFLAGS="-I$with_check/include"
|
|
CHECK_LIBS="-L$with_check/lib -lcheck"
|
|
else
|
|
CHECK_CFLAGS=""
|
|
CHECK_LIBS="-lcheck"
|
|
fi
|
|
|
|
ac_save_CFLAGS="$CFLAGS"
|
|
ac_save_LIBS="$LIBS"
|
|
|
|
CFLAGS="$CFLAGS $CHECK_CFLAGS"
|
|
LIBS="$CHECK_LIBS $LIBS"
|
|
|
|
rm -f conf.check-test
|
|
AC_TRY_RUN([
|
|
#include <stdio.h>
|
|
#include <stdlib.h>
|
|
|
|
#include <check.h>
|
|
|
|
int main ()
|
|
{
|
|
int major, minor, micro;
|
|
char *tmp_version;
|
|
|
|
system ("touch conf.check-test");
|
|
|
|
/* HP/UX 9 (%@#!) writes to sscanf strings */
|
|
tmp_version = strdup("$min_check_version");
|
|
if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, µ) != 3) {
|
|
printf("%s, bad version string\n", "$min_check_version");
|
|
return 1;
|
|
}
|
|
|
|
if ((CHECK_MAJOR_VERSION != check_major_version) ||
|
|
(CHECK_MINOR_VERSION != check_minor_version) ||
|
|
(CHECK_MICRO_VERSION != check_micro_version))
|
|
{
|
|
printf("\n*** The check header file (version %d.%d.%d) does not match\n",
|
|
CHECK_MAJOR_VERSION, CHECK_MINOR_VERSION, CHECK_MICRO_VERSION);
|
|
printf("*** the check library (version %d.%d.%d).\n",
|
|
check_major_version, check_minor_version, check_micro_version);
|
|
return 1;
|
|
}
|
|
|
|
if ((check_major_version > major) ||
|
|
((check_major_version == major) && (check_minor_version > minor)) ||
|
|
((check_major_version == major) && (check_minor_version == minor) && (check_micro_version >= micro)))
|
|
{
|
|
return 0;
|
|
}
|
|
else
|
|
{
|
|
printf("\n*** An old version of check (%d.%d.%d) was found.\n",
|
|
check_major_version, check_minor_version, check_micro_version);
|
|
printf("*** You need a version of check being at least %d.%d.%d.\n", major, minor, micro);
|
|
printf("***\n");
|
|
printf("*** If you have already installed a sufficiently new version, this error\n");
|
|
printf("*** probably means that the wrong copy of the check library and header\n");
|
|
printf("*** file is being found. Rerun configure with the --with-check=PATH option\n");
|
|
printf("*** to specify the prefix where the correct version was installed.\n");
|
|
}
|
|
|
|
return 1;
|
|
}
|
|
],, no_check=yes, [echo $ac_n "cross compiling; assumed OK... $ac_c"])
|
|
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
LIBS="$ac_save_LIBS"
|
|
|
|
if test "x$no_check" = x ; then
|
|
AC_MSG_RESULT(yes)
|
|
ifelse([$2], , :, [$2])
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
if test -f conf.check-test ; then
|
|
:
|
|
else
|
|
echo "*** Could not run check test program, checking why..."
|
|
CFLAGS="$CFLAGS $CHECK_CFLAGS"
|
|
LIBS="$CHECK_LIBS $LIBS"
|
|
AC_TRY_LINK([
|
|
#include <stdio.h>
|
|
#include <stdlib.h>
|
|
|
|
#include <check.h>
|
|
], , [ echo "*** The test program compiled, but did not run. This usually means"
|
|
echo "*** that the run-time linker is not finding check. You'll need to set your"
|
|
echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
|
|
echo "*** to the installed location Also, make sure you have run ldconfig if that"
|
|
echo "*** is required on your system"
|
|
echo "***"
|
|
echo "*** If you have an old version installed, it is best to remove it, although"
|
|
echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
|
|
[ echo "*** The test program failed to compile or link. See the file config.log for"
|
|
echo "*** the exact error that occured." ])
|
|
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
LIBS="$ac_save_LIBS"
|
|
fi
|
|
|
|
CHECK_CFLAGS=""
|
|
CHECK_LIBS=""
|
|
|
|
rm -f conf.check-test
|
|
ifelse([$3], , AC_MSG_ERROR([check not found]), [$3])
|
|
fi
|
|
|
|
AC_SUBST(CHECK_CFLAGS)
|
|
AC_SUBST(CHECK_LIBS)
|
|
|
|
rm -f conf.check-test
|
|
|
|
fi
|
|
])
|