# /****************************************************************************
#  * <Novell-copyright>
#  * Copyright (c) 2001 Novell, Inc. All Rights Reserved.
#  *
#  * This program is free software; you can redistribute it and/or
#  * modify it under the terms of version 2 of the GNU General Public License
#  * as published by the Free Software Foundation.
#  *
#  * This program is distributed in the hope that it will be useful,
#  * but WITHOUT ANY WARRANTY; without even the implied warranty of
#  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  * GNU General Public License for more details.
#  *
#  * You should have received a copy of the GNU General Public License
#  * along with this program; if not, contact Novell, Inc.
#  *
#  * To contact Novell about this file by physical or electronic mail, you
#  * may find current contact information at www.novell.com.
#  * </Novell-copyright>
#  ****************************************************************************/

find_path(Mailutils_INCLUDE_DIR NAMES mailutils/sieve.h)
find_library(Mailutils_LIBRARY NAMES mailutils)
find_library(Mailutils_SIEVE_LIBRARY NAMES mu_sieve)

set(Mailutils_Sieve_FOUND FALSE)
if(Mailutils_SIEVE_LIBRARY)
  set(Mailutils_Sieve_FOUND TRUE)
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(Mailutils
  REQUIRED_VARS Mailutils_LIBRARY Mailutils_INCLUDE_DIR
  HANDLE_COMPONENTS)

if(Mailutils_FOUND AND NOT TARGET Mailutils::Mailutils)
  add_library(Mailutils::Mailutils UNKNOWN IMPORTED)
  set_target_properties(Mailutils::Mailutils PROPERTIES
    IMPORTED_LOCATION "${Mailutils_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${Mailutils_INCLUDE_DIR}")
endif()

if(Mailutils_SIEVE_LIBRARY)
  if(NOT TARGET Mailutils::Sieve)
    add_library(Mailutils::Sieve UNKNOWN IMPORTED)
    set_target_properties(Mailutils::Sieve PROPERTIES
      IMPORTED_LOCATION "${Mailutils_SIEVE_LIBRARY}"
      INTERFACE_LINK_LIBRARIES Mailutils::Mailutils
      INTERFACE_INCLUDE_DIRECTORIES "${Mailutils_INCLUDE_DIR}")
  endif()
endif()

mark_as_advanced(Mailutils_INCLUDE_DIR Mailutils_LIBRARY Mailutils_SIEVE_LIBRARY)