# /****************************************************************************
#  * <Novell-copyright>
#  * Copyright (c) 2001 Novell, Inc. All Rights Reserved.
#  *
#  * This program is free software; you can redistribute it and/or
#  * modify it under the terms of version 2 of the GNU General Public License
#  * as published by the Free Software Foundation.
#  *
#  * This program is distributed in the hope that it will be useful,
#  * but WITHOUT ANY WARRANTY; without even the implied warranty of
#  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  * GNU General Public License for more details.
#  *
#  * You should have received a copy of the GNU General Public License
#  * along with this program; if not, contact Novell, Inc.
#  *
#  * To contact Novell about this file by physical or electronic mail, you
#  * may find current contact information at www.novell.com.
#  * </Novell-copyright>
#  ****************************************************************************/

find_path(LibGcrypt_INCLUDE_DIR NAMES gcrypt.h)
find_library(LibGcrypt_LIBRARY NAMES gcrypt)

if(LibGcrypt_INCLUDE_DIR)
  file(STRINGS "${LibGcrypt_INCLUDE_DIR}/gcrypt.h" _LibGcrypt_VERSION_LINE
    REGEX "^#define GCRYPT_VERSION[ \t]+\"[0-9]+\\.[0-9]+\\.[0-9]+")
  string(REGEX MATCH "\"([0-9]+\\.[0-9]+\\.[0-9]+)"
    _LibGcrypt_VERSION_MATCH "${_LibGcrypt_VERSION_LINE}")
  set(LibGcrypt_VERSION "${CMAKE_MATCH_1}")
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(LibGcrypt
  REQUIRED_VARS LibGcrypt_LIBRARY LibGcrypt_INCLUDE_DIR
  VERSION_VAR LibGcrypt_VERSION)

if(LibGcrypt_FOUND AND NOT TARGET LibGcrypt::LibGcrypt)
  add_library(LibGcrypt::LibGcrypt UNKNOWN IMPORTED)
  set_target_properties(LibGcrypt::LibGcrypt PROPERTIES
    IMPORTED_LOCATION "${LibGcrypt_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${LibGcrypt_INCLUDE_DIR}")
endif()

mark_as_advanced(LibGcrypt_INCLUDE_DIR LibGcrypt_LIBRARY)