# /****************************************************************************
#  * <Novell-copyright>
#  * Copyright (c) 2001 Novell, Inc. All Rights Reserved.
#  *
#  * This program is free software; you can redistribute it and/or
#  * modify it under the terms of version 2 of the GNU General Public License
#  * as published by the Free Software Foundation.
#  *
#  * This program is distributed in the hope that it will be useful,
#  * but WITHOUT ANY WARRANTY; without even the implied warranty of
#  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  * GNU General Public License for more details.
#  *
#  * You should have received a copy of the GNU General Public License
#  * along with this program; if not, contact Novell, Inc.
#  *
#  * To contact Novell about this file by physical or electronic mail, you
#  * may find current contact information at www.novell.com.
#  * </Novell-copyright>
#  ****************************************************************************/

find_path(OATH_INCLUDE_DIR NAMES liboath/oath.h)
find_library(OATH_LIBRARY NAMES oath)

if(OATH_INCLUDE_DIR)
  file(STRINGS "${OATH_INCLUDE_DIR}/liboath/oath.h" _OATH_VERSION_LINE
    REGEX "^# *define OATH_VERSION +\"[0-9]+\\.[0-9]+\\.[0-9]+\"")
  string(REGEX MATCH "[0-9]+\\.[0-9]+\\.[0-9]+" OATH_VERSION
    "${_OATH_VERSION_LINE}")
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(OATH
  REQUIRED_VARS OATH_LIBRARY OATH_INCLUDE_DIR
  VERSION_VAR OATH_VERSION)

if(OATH_FOUND AND NOT TARGET OATH::OATH)
  add_library(OATH::OATH UNKNOWN IMPORTED)
  set_target_properties(OATH::OATH PROPERTIES
    IMPORTED_LOCATION "${OATH_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${OATH_INCLUDE_DIR}")
endif()

mark_as_advanced(OATH_INCLUDE_DIR OATH_LIBRARY)