set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Mail and calendering made simple")
set(CPACK_PACKAGE_VENDOR "Bongo Project")
set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
set(CPACK_PACKAGE_VERSION_MAJOR "${PROJECT_VERSION_MAJOR}")
set(CPACK_PACKAGE_VERSION_MINOR "${PROJECT_VERSION_MINOR}")
set(CPACK_PACKAGE_VERSION_PATCH "${PROJECT_VERSION_PATCH}")
set(BONGO_SOURCE_PACKAGE_VERSION "${PROJECT_VERSION}")
find_package(Git QUIET)
if(Git_FOUND AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/.git")
    execute_process(
        COMMAND "${GIT_EXECUTABLE}" describe --exact-match --tags
                --match "${PROJECT_VERSION}" --match "v${PROJECT_VERSION}"
        WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
        RESULT_VARIABLE BONGO_RELEASE_TAG_RESULT
        OUTPUT_QUIET
        ERROR_QUIET)
    if(NOT BONGO_RELEASE_TAG_RESULT EQUAL 0)
        execute_process(
            COMMAND "${GIT_EXECUTABLE}" rev-parse --short=7 HEAD
            WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
            RESULT_VARIABLE BONGO_GIT_REVISION_RESULT
            OUTPUT_VARIABLE BONGO_GIT_REVISION
            OUTPUT_STRIP_TRAILING_WHITESPACE
            ERROR_QUIET)
        if(BONGO_GIT_REVISION_RESULT EQUAL 0)
            string(APPEND BONGO_SOURCE_PACKAGE_VERSION
                "-dev${BONGO_GIT_REVISION}")
        endif()
    endif()
endif()
set(CPACK_SOURCE_PACKAGE_FILE_NAME
    "${PROJECT_NAME}-${BONGO_SOURCE_PACKAGE_VERSION}")
set(CPACK_SOURCE_IGNORE_FILES
    "/\\.git/"
    "/\\.git$"
    "/__pycache__/"
    "\\.py[co]$"
    "/CMakeFiles/"
    "/CMakeCache\\.txt$"
    "/cmake_install\\.cmake$"
    "/Makefile$"
    "~$"
    "\\.sw[op]$")
set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}")

# Several legacy install rules use absolute destinations derived from
# CMAKE_INSTALL_PREFIX.  Always stage those paths below CPack's temporary
# directory; package generation must never write into the host filesystem.
set(CPACK_SET_DESTDIR ON)


include(CPack)