# /****************************************************************************
#  * <Novell-copyright>
#  * Copyright (c) 2001 Novell, Inc. All Rights Reserved.
#  *
#  * This program is free software; you can redistribute it and/or
#  * modify it under the terms of version 2 of the GNU General Public License
#  * as published by the Free Software Foundation.
#  *
#  * This program is distributed in the hope that it will be useful,
#  * but WITHOUT ANY WARRANTY; without even the implied warranty of
#  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  * GNU General Public License for more details.
#  *
#  * You should have received a copy of the GNU General Public License
#  * along with this program; if not, contact Novell, Inc.
#  *
#  * To contact Novell about this file by physical or electronic mail, you
#  * may find current contact information at www.novell.com.
#  * </Novell-copyright>
#  ****************************************************************************/

find_path(LibIDN2_INCLUDE_DIR NAMES idn2.h)
find_library(LibIDN2_LIBRARY NAMES idn2)

if(LibIDN2_INCLUDE_DIR)
  file(STRINGS "${LibIDN2_INCLUDE_DIR}/idn2.h" _LibIDN2_VERSION_LINE
    REGEX "^#[ \t]*define IDN2_VERSION[ \t]+\"[0-9]+\\.[0-9]+\\.[0-9]+\"")
  string(REGEX MATCH "\"([0-9]+\\.[0-9]+\\.[0-9]+)\""
    _LibIDN2_VERSION_MATCH "${_LibIDN2_VERSION_LINE}")
  set(LibIDN2_VERSION "${CMAKE_MATCH_1}")
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(LibIDN2
  REQUIRED_VARS LibIDN2_LIBRARY LibIDN2_INCLUDE_DIR
  VERSION_VAR LibIDN2_VERSION)

if(LibIDN2_FOUND AND NOT TARGET LibIDN2::LibIDN2)
  add_library(LibIDN2::LibIDN2 UNKNOWN IMPORTED)
  set_target_properties(LibIDN2::LibIDN2 PROPERTIES
    IMPORTED_LOCATION "${LibIDN2_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${LibIDN2_INCLUDE_DIR}")
endif()

mark_as_advanced(LibIDN2_INCLUDE_DIR LibIDN2_LIBRARY)