cmake_minimum_required(VERSION 3.20)

project(prozgui VERSION 2.4.8 LANGUAGES C CXX)

include(GNUInstallDirs)
find_package(Threads REQUIRED)
find_package(FLTK REQUIRED)
find_package(Intl)
find_package(libprozilla CONFIG REQUIRED)

set(ENABLE_NLS ${Intl_FOUND})

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS ON)
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS ON)

set(PACKAGE "prozgui")
set(PACKAGE_NAME "prozgui")
set(PACKAGE_VERSION "${PROJECT_VERSION}")
set(VERSION "${PROJECT_VERSION}")
set(LOCALEDIR "${CMAKE_INSTALL_FULL_LOCALEDIR}")
set(GLOBAL_CONF_FILE "${CMAKE_INSTALL_FULL_SYSCONFDIR}/prozilla.conf")
configure_file(cmake/config.h.in generated/config.h)

add_subdirectory(src)
add_subdirectory(man)
add_subdirectory(po)

install(FILES data/prozgui.desktop
  DESTINATION "${CMAKE_INSTALL_DATADIR}/applications")
install(FILES src/BigProZilla01.xpm
  DESTINATION "${CMAKE_INSTALL_DATADIR}/pixmaps"
  RENAME prozgui.xpm)

set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "FLTK graphical interface for ProZilla")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
set(CPACK_GENERATOR "TGZ;TXZ")
set(CPACK_SOURCE_GENERATOR "TGZ;TXZ")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${PROJECT_VERSION}")
set(CPACK_SOURCE_IGNORE_FILES
    "/\\.git/"
    "/build/"
    "/_CPack_Packages/"
    "/CMakeFiles/"
    "/CMakeCache\\.txt$"
    "/cmake_install\\.cmake$"
    "/CPack(Config|SourceConfig)\\.cmake$"
    "~$"
    ${CPACK_SOURCE_IGNORE_FILES})
include(CPack)